Temperature Logging with ESP8266

technology , business

Temperature Logging

We had to do some temperature monitoring of some classrooms during winter time and I felt it was a good time to deploy some ESP8266 devices out in the classrooms as temperature loggers. These would send payloads to a new MQTT server which could be read by any subscriber. While I did toy around with the idea of writing directly to our MySQL server, we decided against it as we did not want additional load on the database server.

The results were excellent; the temperatures were well within 0.2 degrees of a commercial thermal probe.

Parts List

Coding

The code was pretty straight forward. Coding was on Arduino 1.8.13 with the ESP8266 addon. Libraries used were OneWire, DallasTemperature and the excellent PubSubClient. We used GPIO Pin 2 as the input pin for the Dallas temperature sensor.

#include <ESP8266WiFi.h>
#include <OneWire.h>
#include <DallasTemperature.h>
#include <PubSubClient.h>

const int oneWireBus = 2;     
OneWire oneWire(oneWireBus);
DallasTemperature sensors(&oneWire);
int numberOfDevices;
DeviceAddress tempDeviceAddress; 

#define wlan_ssid ""
#define wlan_pass ""

#define mqtt_device ""
#define mqtt_server ""
#define mqtt_user ""
#define mqtt_password ""

#define temperature_topic ""

WiFiClient espClient;
PubSubClient client(espClient);

void setup()
{
  Serial.begin(115200);
  connectToWifi();
  client.setServer(mqtt_server, 1883);
  sensors.begin();
  
  Serial.print("Locating devices...");
  Serial.print("Found ");
  numberOfDevices = sensors.getDeviceCount();
  Serial.print(numberOfDevices, DEC);
  Serial.println(" devices.");

 for(int i=0;i<numberOfDevices; i++)
 {
    if(sensors.getAddress(tempDeviceAddress, i))
    {
      Serial.print("Found device ");
      Serial.print(i, DEC);
      Serial.print(" with address: ");
      printAddress(tempDeviceAddress);
      printResolution(tempDeviceAddress);
      Serial.println();
    } else {
      Serial.print("Found ghost device at ");
      Serial.print(i, DEC);
      Serial.print(" but could not detect address. Check power and cabling");
    }
  }
  
  Serial.print("Parasite power is: ");
  if (sensors.isParasitePowerMode())
    Serial.println("ON");
  else
    Serial.println("OFF");
    
}

void printAddress(DeviceAddress deviceAddress)
{
  for (uint8_t i = 0; i < 8; i++)
  {
    if (deviceAddress[i] < 16)
      Serial.print("0");
      Serial.print(deviceAddress[i], HEX);
  }
  Serial.println();
}

void printResolution(DeviceAddress deviceAddress)
{
  Serial.print("Resolution : ");
  Serial.print(sensors.getResolution(deviceAddress));
  Serial.println();   
}

void connectToWifi()
{
  delay(5);
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(wlan_ssid);

  WiFi.begin(wlan_ssid, wlan_pass);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
 
  Serial.println();
  Serial.println("WiFi connected");
  Serial.println("IP address: "); 
  Serial.println(WiFi.localIP());
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect(mqtt_device, mqtt_user, mqtt_password)) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

bool checkBound(float newValue, float prevValue, float maxDiff)
{
  return !isnan(newValue) &&
         (newValue < prevValue - maxDiff || newValue > prevValue + maxDiff);
}

long lastMsg = 0;
float temp = 0.0;
float hum = 0.0;
float diff = 0.1;

void loop()
{
  if (!client.connected())
  {
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - lastMsg > 1000)
  {
    lastMsg = now;
   
    sensors.requestTemperatures(); 
    float temperatureC = sensors.getTempCByIndex(0);

    if (checkBound(temperatureC, temp, diff))
    {
      temp = temperatureC;
      Serial.print("New temperature detected : ");
      Serial.print(String(temp).c_str());
      Serial.println("ºC");
      client.publish(temperature_topic, String(temp).c_str(), true);
    }
    Serial.println(temperatureC);
    delay(5000);
  }
}